' FileX_Ass.vbs
'========================   Описание   =====================================
' Сканирует секцию [Associations] и записывает информацию в файлы
' для дальнейшего отображения ассоциаций в колонках через плагин FileX.wdx
'
' Автор:         Аверин Андрей
' Версия:      1.2 (11.12.2010 - 21.11.2011)
' Mail:             Averin-And@yandex.ru
' Site:              http://tc-image.3dn.ru/forum/3-451-1345-16-1334756599
'========================================================================
TC = CreateObject("WScript.Shell").ExpandEnvironmentStrings("%COMMANDER_PATH%")
TCAss = TC & "\WinAssociations.ini"
FXAssIcon = TC & "\Plugins\wdx\FileX_Ass\FileX_AssIconN.ini"
FXAssProgram = TC & "\Plugins\wdx\FileX_Ass\FileX_AssProg.ini"
FXAssIconPath = TC & "\Plugins\wdx\FileX_Ass\FileX_AssIcon.ini"

INI = TC & "\Scripts\Include\FunctionsINIRWS.vbs"
Execute CreateObject("Scripting.FileSystemObject").OpenTextFile(INI).ReadAll

WriteINISection FXAssProgram, "Group", " "
WriteINISection FXAssIconPath, "Group", " "
WriteINISection FXAssIcon, "Group", " "

For i = 1 To 250
    FilterStr = ReadINI(TCAss, "Associations", "Filter" & i)
    If Len(FilterStr) = 0 Then Wscript.Quit

    If InStrRev(FilterStr,"|") > 0 Then
      FilterStr = Replace(Trim(Replace(Left(FilterStr,InStrRev(FilterStr,"|")-1), "*." ,"")),";",":")
    Else
      FilterStr = Replace(Trim(Replace(FilterStr, "*." ,"")),";",":")
    End if

    ProgStr = ReadINI(TCAss, "Associations", "Filter" & i & "_open")
    If Len(ProgStr) < 2 or ProgStr = "" Then
      ProgStr = "----"
    Else
      ProgStr = Trim(Replace(Replace(ProgStr, Chr(34), ""), "%1",""))
    End if

    IconStr = ReadINI(TCAss, "Associations", "Filter" & i & ".icon")

    If Len(IconStr) < 10 Then
      IconPath = "----" : IconNumer = "----"
    Else
      IconPath = Left(IconStr, InStrRev(IconStr,",") - 1)
      IconNumer = Right(IconStr, Len(IconStr) - InStrRev(IconStr,","))
    End if

    WriteINI FXAssProgram, "Group", ProgStr & " [" & i & "]", FilterStr
    WriteINI FXAssIconPath, "Group", IconPath & " [" & i & "]", FilterStr   
    WriteINI FXAssIcon, "Group", IconNumer & " [" & i & "]", FilterStr   
Next